Le site officiel de l'Arduino est [http://www.arduino.cc/]. C'est là qu'on trouvera l'IDE de développement pour les Arduinos [http://arduino.cc/en/Main/Software] :

Le fichier téléchargé [1] est un zip qui une fois décompressé donne l'arborescence [2]. On pourra lancer l'IDE en double-cliquant sur l'exécutable [3].

Afin que l'IDE puisse communiquer avec un Arduino, il faut que ce dernier soit reconnu par le PC hôte. Pour cela, on pourra procéder de la façon suivante :

• brancher l'Arduino sur un port USB de l'ordinateur hôte ;
• le système va alors tenter de trouver le pilote du nouveau périphérique USB. Il ne va pas le trouver. Indiquez alors que le pilote est sur le disque à l'endroit <arduino>/drivers où <arduino> est le dossier d'installation

Pour tester l'IDE, on pourra procéder de la façon suivante :

• lancer l'IDE ;
• connecter l'Arduino au PC via son câble USB. Pour l'instant, ne pas inclure la carte réseau ;
• en [1], choisissez le type de la carte Arduino connectée au port USB ;
• en [2], indiquez le port USB sur lequel l'Arduino est connectée. Pour le savoir, débranchez l'Arduino et notez les ports. Rebranchez-le et vérifiez de nouveau les ports : celui qui a été rajouté est celui de l'Arduino ;

Exécutez certains des exemples inclus dans l'IDE :

L'exemple est chargé et affiché :

Les exemples qui accompagnent l'IDE sont très didactiques et très bien commentés. Un code Arduino est écrit en langage C et se compose de deux parties bien distinctes :

• une fonction [setup] qui s'exécute une seule fois au démarrage de l'application, soit lorsque celle-ci est " téléversée " du PC hôte sur l'Arduino, soit lorsque l'application est déjà présente sur l'Arduino et qu'on appuie sur le bouton [Reset]. C'est là qu'on met le code d'initialisation de l'application ;
• une fonction [loop] qui s'exécute continuellement (boucle infinie). C'est là qu'on met le coeur de l'application.

Ici,

• la fonction [setup] configure la pin n° 13 en sortie ;
• la fonction [loop] l'allume et l'éteint de façon répétée : la led s'allume et s'éteint toutes les secondes.

Le programme affiché est transféré (téléversé) sur l'Arduino avec le bouton [1]. Une fois transféré, il s'exécute et la led n° 13 se met à clignoter indéfiniment.

L'Arduino ou les Arduinos et le PC hôte doivent être sur un même réseau privé :

S'il n'y a qu'un Arduino, on pourra le relier au PC hôte par un simple câble RJ 45. S'il y en a plus d'un, le PC hôte et les Arduinos seront mis sur le même réseau par un mini-hub.

On mettra le PC hôte et les Arduinos sur le réseau privé 192.168.2.x.

• l'adresse IP des Arduinos est fixée par le code source. Nous verrons comment ;
• l'adresse IP de l'ordinateur hôte pourra être fixée comme suit :
• prendre l'option [Panneau de configuration\Réseau et Internet\Centre Réseau et partage] :
• en [1], suivre le lien [Connexion au réseau local]
• en [2], visualiser les propriétés de la connexion ;
• en [4], visualiser les propriétés IP v4 [3] de la connexion ;
• en [5], donner l'adresse IP [192.168.2.1] à l'ordinateur hôte ;
• en [6], donner le masque [255.255.255.0] au réseau ;
• valider le tout en [7].

Avec l'IDE, chargez l'exemple [Exemples / Ethernet / WebServer] :

 

Sélectionnez

1.
2.
3.
4.
5.
6.
7.
8.
9.
10.
11.
12.
13.
14.
15.
16.
17.
18.
19.
20.
21.
22.
23.
24.
25.
26.
27.
28.
29.
30.
31.
32.
33.
34.
35.
36.
37.
38.
39.
40.
41.
42.
43.
44.
45.
46.
47.
48.
49.
50.
51.
52.
53.
54.
55.
56.
57.
58.
59.
60.
61.
62.
63.
64.
65.
66.
67.
68.
69.
70.
71.
72.
73.
74.
75.
76.
77.
78.
79.
80.
81.
82.
83.
84.
85.
86.
87.
88.
89.
90.
91.
92.
93.
94.
95.
96.
97.
98.
99.
100.

/*
  Web Server
 
 A simple web server that shows the value of the analog input pins.
 using an Arduino Wiznet Ethernet shield. 
 
 Circuit:
 * Ethernet shield attached to pins 10, 11, 12, 13
 * Analog inputs attached to pins A0 through A5 (optional)
 
 created 18 Dec 2009
 by David A. Mellis
 modified 9 Apr 2012
 by Tom Igoe
 
 */

#include <SPI.h>
#include <Ethernet.h>

// Enter a MAC address and IP address for your controller below.
// The IP address will be dependent on your local network:
byte mac[] = { 
  0xDE, 0xAD, 0xBE, 0xEF, 0xFE, 0xED };
IPAddress ip(192,168,1, 177);

// Initialize the Ethernet server library
// with the IP address and port you want to use 
// (port 80 is default for HTTP):
EthernetServer server(80);

void setup() {
 // Open serial communications and wait for port to open:
  Serial.begin(9600);
   while (!Serial) {
    ; // wait for serial port to connect. Needed for Leonardo only
  }


  // start the Ethernet connection and the server:
  Ethernet.begin(mac, ip);
  server.begin();
  Serial.print("server is at ");
  Serial.println(Ethernet.localIP());
}


void loop() {
  // listen for incoming clients
  EthernetClient client = server.available();
  if (client) {
    Serial.println("new client");
    // an http request ends with a blank line
    boolean currentLineIsBlank = true;
    while (client.connected()) {
      if (client.available()) {
        char c = client.read();
        Serial.write(c);
        // if you've gotten to the end of the line (received a newline
        // character) and the line is blank, the http request has ended,
        // so you can send a reply
        if (c == '\n' && currentLineIsBlank) {
          // send a standard http response header
          client.println("HTTP/1.1 200 OK");
          client.println("Content-Type: text/html");
          client.println("Connection: close");
          client.println();
          client.println("<!DOCTYPE HTML>");
          client.println("<html>");
                    // add a meta refresh tag, so the browser pulls again every 5 seconds:
          client.println("<meta http-equiv=\"refresh\" content=\"5\">");
          // output the value of each analog input pin
          for (int analogChannel = 0; analogChannel < 6; analogChannel++) {
            int sensorReading = analogRead(analogChannel);
            client.print("analog input ");
            client.print(analogChannel);
            client.print(" is ");
            client.print(sensorReading);
            client.println("<br />");       
          }
          client.println("</html>");
          break;
        }
        if (c == '\n') {
          // you're starting a new line
          currentLineIsBlank = true;
        } 
        else if (c != '\r') {
          // you've gotten a character on the current line
          currentLineIsBlank = false;
        }
      }
    }
    // give the web browser time to receive the data
    delay(1);
    // close the connection:
    client.stop();
    Serial.println("client disconnected");
  }
}

Cette application crée un serveur web sur le port 80 (ligne 30) à l'adresse IP de la ligne 25. L'adresse MAC de la ligne 23 est l'adresse MAC indiquée sur la carte réseau de l'Arduino.

La fonction [setup] initialise le serveur web :

• ligne 34 : initialise le port série sur lequel l'application va faire des logs. Nous allons suivre ceux-ci ;
• ligne 41 : le noeud TCP-IP (IP, port) est initialisé ;
• ligne 42 : le serveur de la ligne 30 est lancé sur ce noeud réseau ;
• lignes 43-44 : on logue l'adresse IP du serveur web ;

La fonction [loop] implémente le serveur web :

• ligne 50 : si un client se connecte au serveur web [server].available rend ce client, sinon rend null ;
• ligne 51 : si le client n'est pas null ;
• ligne 55 : tant que le client est connecté ;
• ligne 56 : [client].available est vrai si le client a envoyé des caractères. Ceux-ci sont stockés dans un buffer. [client].available rend vrai tant que ce buffer n'est pas vide ;
• ligne 57 : on lit un caractère envoyé par le client ;
• ligne 58 : ce caractère est affiché en écho sur la console de logs ;
• ligne 62 : dans le protocole HTTP, le client et le serveur échangent des lignes de texte.
• le client envoie une requête HTTP au serveur web en lui envoyant une série de lignes de texte terminées par une ligne vide,
• le serveur répond alors au client en lui envoyant une réponse et en fermant la connexion ;

Ligne 62, le serveur ne fait rien avec les entêtes HTTP qu'il reçoit du client. Il attend simplement la ligne vide : une ligne qui contient le seul caractère \n ;

• lignes 64-67 : le serveur envoie au client les lignes de texte standard du protocole HTTP. Elles se terminent par une ligne vide (ligne 67) ;
• à partir de la ligne 68, le serveur envoie un document à son client. Ce document est généré dynamiquement par le serveur et est au format HTML (lignes 68-69) ;
• ligne 71 : une ligne HTML particulière qui demande au navigateur client de rafraîchir la page toutes les 5 secondes. Ainsi le navigateur va demander la même page toutes les 5 secondes ;
• lignes 73-80 : le serveur envoie au navigateur client, les valeurs des 6 entrées analogiques de l'Arduino ;
• ligne 81 : le document HTML est fermé ;
• ligne 82 : on sort de la boucle while de la ligne 55 ;
• ligne 97 : la connexion avec le client est fermée ;
• ligne 98 : on logue l'événement dans la console de logs ;
• ligne 100 : on reboucle sur le début de la fonction loop : le serveur va se remettre à l'écoute des clients. Nous avons dit que le navigateur client allait redemander la même page toutes les 5 secondes. Le serveur sera là pour lui répondre de nouveau.

Modifiez le code en ligne 25 pour y mettre l'adresse IP de votre Arduino, par exemple :

IPAddress ip(192,168,2,2);

Téléversez le programme sur l'Arduino. Lancez la console de logs (Ctrl-M) (M majuscule) :

• en [1], la console de logs. Le serveur a été lancé ;
• en [2], avec un navigateur, on demande l'adresse IP de l'Arduino. Ici [192.168.2.2] est traduit par défaut comme [http://198.162.2.2:80];
• en [3], les informations envoyées par le serveur web. Si on visualise le code source de la page du navigateur, on obtient :

 

Sélectionnez

1.
2.
3.
4.
5.
6.
7.
8.
9.
10.

<!DOCTYPE HTML>
<html>
<meta http-equiv="refresh" content="5">
analog input 0 is 1023<br />
analog input 1 is 1023<br />
analog input 2 is 727<br />
analog input 3 is 543<br />
analog input 4 is 395<br />
analog input 5 is 310<br />
</html>

On reconnaît là, les lignes de texte envoyées par le serveur. Du côté Arduino, la console de logs affiche ce que le client lui envoie :

 

Sélectionnez

1.
2.
3.
4.
5.
6.
7.
8.
9.
10.
11.

new client
GET /favicon.ico HTTP/1.1
Host: 192.168.2.2
Connection: keep-alive
Accept: */*
User-Agent: Mozilla/5.0 (Windows NT 6.2; WOW64) AppleWebKit/537.22 (KHTML, like Gecko) Chrome/25.0.1364.172 Safari/537.22
Accept-Encoding: gzip,deflate,sdch
Accept-Language: fr-FR,fr;q=0.8,en-US;q=0.6,en;q=0.4
Accept-Charset: ISO-8859-1,utf-8;q=0.7,*;q=0.3

client disconnected

• lignes 2-9 : des entêtes HTTP standard ;
• ligne 10 : la ligne vide qui les termine.

Etudiez bien cet exemple. Il donne des indications qui vous seront utiles pour construire un serveur Arduino pour le TP.

Dans le TP à écrire, les Arduinos échangent des lignes de texte au format JSON avec leurs clients. Par défaut, l'IDE Arduino n'inclut pas de bibliothèque pour gérer le JSON. Nous allons installer la bibliothèque aJson disponible à l'URL [https://github.com/interactive-matter/aJson].

• en [1], téléchargez la version zippée du dépôt Github ;
• décompressez le dossier et copiez le dossier [aJson-master] [3] dans le dossier [<arduino>/libraries] [3] où <arduino> est le dossier d'installation de l'IDE Arduino ;
• en [4], renommez ce dossier [aJson] ;
• en [5], son contenu.

Maintenant, lancez l'IDE Arduino :

Vérifiez que dans les exemples vous avez désormais des exemples pour la bibliothèque aJson. Exécutez et étudiez ces exemples. Vous en aurez besoin.